se ho ben capito cio che vuoi fare, e' piu o meno quello che faccio io: lanciare una sessione di pose ed andare a dormire. Automaticamente vorresti che a fine pose tutto si accomodasse automaticamente: si ferma la guida, la montatura va in park, spegli il CCD, e se possibile, togli anche la corrente al tutto (io lo faccio).
io usavo questo script (che ingloba anche il warm-up del ccd) che va adattato alla tua montatura :
Codice:
Dim cam
Dim ho
Dim tel
Const StepTime = 10 'Interval for warm-up (seconds)
Const StepTemp = 3 'Interval (dg Celcius)
Const AmbientTemp = 2 'Target temprature
'
' ---------------parte telescopio --------------------
'
'
'Set tel = CreateObject("ScopeSim.Telescope") 'simulatore ASCOM
Set tel = CreateObject("Celestron.Telescope") 'sostituire questa linea con il driver del proprio telescopio.
tel.Connected = True
tel.Tracking = False
wscript.echo "Telescope tracking stopped.."
'
' ---------------end parte telescopio ----------------
'
Set cam = CreateObject("MaxIm.CCDCamera")
cam.LinkEnabled = True
if Not cam.LinkEnabled Then
MsgBox "Failed to start camera."
wscript.Quit
End If
cam.DisableAutoShutdown = True
cam.CoolerOn = True
'
'----------------fermare la guida---------------------
'
cam.GuiderStop()
wscript.echo "Guide stopped.."
'
'----------------inizio warm up cooler ---------------
'
Set ho = CreateObject("DriverHelper.Util")
wscript.echo "Starting Warm-UP : Camera temprature : " & cam.Temperature
Do While (cam.Temperature < AmbientTemp)
ho.WaitForMilliseconds(StepTime*1000)
wscript.echo "10 sec : temperature = " & cam.Temperature
if (cam.CameraStatus = 1) or (cam.CoolerOn = False) Then
MsgBox "X Camera communication/cooler problem!"
wscript.Quit
End If
'check if temprature is stabilized, then increase, else wait another StepTime seconds
if (cam.TemperatureSetpoint - cam.Temperature) <= 1 then
cam.TemperatureSetpoint = cam.Temperature + StepTemp
wscript.echo "new set point =" & cam.TemperatureSetpoint
end if
Loop
wscript.echo "Warm up eneded : Camera Temperature " & cam.Temperature
cam.TemperatureSetpoint = AmbientTemp
cam.CoolerOn = False
wscript.echo "CCD cooler OFF.."
'
'------------------End Warm up--------------------------
'
'MsgBox "Target temperature threshold reached! CCD Cooler OFF"
'------------------Spegnere il telescopio e CCD ---------------
Dim WSHShell
Dim WSHShell2
Set WSHShell = WScript.CreateObject("WScript.Shell")
' open normal and do not wait
WSHShell.Run chr(34) & "C:\Programmi\Power Manager\pm.exe" & chr(34) & "-off -telescopio -ccd", 1, false
Set WSHShell = Nothing
wscript.echo "ccd spento"
Set WSHShell = WScript.CreateObject("WScript.Shell")
WSHShell.Run chr(34) & "C:\Programmi\Power Manager\pm.exe" & chr(34) & "-off -telescopio -montatura", 1, false
Set WSHShell = Nothing
wscript.echo "ccd spento"
'
MsgBox "all command done"
wscript.Quit
adesso non ho controllato se e' quello che funziona (no ho tante versioni che mi sono perso), ma la linea guida e' qui dentro.
in pratica:
a) si connette alla montatura (devi capire come indirizzare la tua, vi e' una linea commentata)
b) spegna il tracking (questo mi basta, io non lo metto in park, basta che non continui andando a sbattere. anzi su questo punto io sono tranquillo avendo impostato i limiti anche al meridiano. )
e) toglie la corrente al tutto con il comando DOS pm.exe (mi comanda l'on/off di prese di una ciabatta USB con dei rele) ovviamente da togliere nel tuo caso, lo lascio solo per farti vedere che potresti lanciare un qualsiasi programma esterno.
in alternativa, prima della ciabatta relè, avevo tutto collegato ad una presa temporizzata che spegnevo ad orario programmato, giusto per non lasciare corrente attiva e non rischiare che una eventuale pioggia facesse danni.
Per "lanciare" questo script a fine posa, utilizza la possibilita di aggiungere script nella schermata "autosave" come indicato qui:
download/file.php?id=37497&mode=viewla foto e' per altro script, ma il discorso e' lo stesso: raggruppa "by slot" il tutto , e fai una posa "fake"(falsa) (di qualche centesimo di secondo) in un ultimo slot in modo da lanciare lo script esattamente quando serve. questo lo trovi descritto nel post che ti ho lincato prima dove si parla di lanciare uno script che effettua una una chiamata Skype per allarmami in caso di problemi.
Fabrizio
PS: (lo script, immagino lo sai, puoi lanciarlo manualmente con il tast "run script" di maxim che trovi nel menu a cascata "FILE" )
PPS: attento al "Group by SLOT". io faccio colore one shot, non so se tu fai pose separate RGB dove tipicamente si fa un loop RGB RGB RGB.. e non RRR GGG BBB ...). Per intenderci, "group by slot" fa il secondo caso.
Home
Iscriviti
La Bacheca
F.A.Q.
Login/Logout
